boa tarde amigos!
preciso entra com um outro adsl no meu mk, mas quero que só alguns cliente passa por ele, e os outros continue no outro adsl
Obs: os dois estão roteador (link a IP: 10.1.1.20) (link b IP: 192.168.0.2)
Versão Imprimível
boa tarde amigos!
preciso entra com um outro adsl no meu mk, mas quero que só alguns cliente passa por ele, e os outros continue no outro adsl
Obs: os dois estão roteador (link a IP: 10.1.1.20) (link b IP: 192.168.0.2)
Citação:
Postado originalmente por willazevedo
https://under-linux.org/showthread.p...errerid=126954
leia , compreenda e execute. não tem erro.
Ok deu certo, mas agora estou com 2 dúvidas, pra eu acessar remoto a rb e liberar portas pra cliente?
Citação:
Postado originalmente por willazevedo
/ip firewall nat
add action=dst-nat chain=dstnat comment="PORTA JOGO DE FULANO" disabled=no \
dst-port=8080 in-interface=SEULINK protocol=tcp to-addresses=\
IPCLIENTE to-ports=8080
Dependendo da versão que você estiver usando só ativar a opção Cloud no Mikrotik.
Boa noite, quanto as portas ok, Mas agora o clone não da "Error: no Internet connection" O QUE PODE SER?Citação:
Postado originalmente por rcardomenezes
tira um print da aba Cloud ai...Citação:
Postado originalmente por willazevedo
já forçou o update?
sim
chegou a alterar a porta de acesso? 8291 ? em services... se está ativado.
alterar? sim esta ativa
então corre pra um DDNS no-ip que dá certo. faz um dominio FREE lá e joga o script no mk
eu preciso fazer rota default? como eu crio?
:local username "usuario"
:local password "senha"
:local hostname "seunome.ddns.net"
#availabe options: "http" or "iface"
# - http: Consulta servidor externo para descobrir o IP (Usado atrás de NAT)
# - iface: Nesta opção pega o IP da Interface de Internet (Nem sempre funciona direito)
:local discoverBy "iface"
# interface used to get ip address from (only if discoverBy = iface)
:local iface "Discador"
# Serviços disponiveis: "dyndns", "noip" and "changeip"
:local service "noip"
# Numero de dias para forçar mudança de IP
:local forceUpdate 15
#************************************************************************************************
# Daqui em diante não faça mudanças, a menos que saiba.
#************************************************************************************************
:local force
:global lastUpdate
:local currentIP
:if ($discoverBy="http") do={
/tool fetch mode=http address="checkip.dyndns.org" src-path="/" dst-path="/dyndns.checkip.html"
:local result [/file get dyndns.checkip.html contents]
:local resultLen [:len $result]
:local startLoc [:find $result ": " -1]
:set startLoc ($startLoc + 2)
:local endLoc [:find $result "</body>" -1]
:set currentIP [:pick $result $startLoc $endLoc]
} else={
:set currentIP [ /ip address get [find interface=$iface disabled=no] address ]
:for i from=( [:len $currentIP] - 1) to=0 do={
:if ( [:pick $currentIP $i] = "/") do={ :set currentIP [:pick $currentIP 0 $i] }
}
}
#get IP from DynDNS for our hostname
:local resolvedIP [:resolve $hostname]
# get current date in format mm/DD/YYYY
:local date [ /system clock get date ]
# convert to YYYYMMDD
:local months ("jan","feb","mar","apr","may","jun","jul","aug","sep","oct","nov","dec");
:local month [ :pick $date 0 3 ]; :local day [ :pick $date 4 6 ]; :local year [ :pick $date 7 11 ];
:local mm ([ :find $months $month -1 ] + 1);
:if ($mm < 10) do={ :set month ("0" . $mm); } else={ :set month $mm; }
:set date ($year . $month . $day);
:if ([ :typeof $lastUpdate ]=[:nothing] || (($date-$lastUpdate) >= $forceUpdate && $forceUpdate > 0)) do={
:set force true
}
:put ("Current IP: $currentIP ($discoverBy), Last update: $lastUpdate")
# Determine if dyndns update is needed
:if (($currentIP != $resolvedIP) || ($force = true)) do={
:if ($service = "dyndns") do={
/tool fetch user=$username password=$password mode=http address="members.dyndns.org" \
src-path="/nic/update?hostname=$hostname&myip=$currentIP" dst-path="/output.txt"
}
:if ($service = "noip") do={
/tool fetch user=$username password=$password mode=http address="dynupdate.no-ip.com" \
src-path="/nic/update?hostname=$hostname&myip=$currentIP" dst-path="/output.txt"
}
:if ($service = "changeip") do={
/tool fetch user=$username password=$password mode=http address="nic.changeip.com" \
src-path="/nic/update?hostname=$hostname&myip=$currentIP" dst-path="/output.txt"
}
:local result [/file get output.txt contents]
:log info ("dynamic-dns-updater: Service = $service, Hostname = $hostname")
:log info ("dynamic-dns-updater: CurrentIP = $currentIP, Resolved IP = $resolvedIP")
:log info ("dynamic-dns-updater: Update result: ".$result)
/ip dns cache flush
:set lastUpdate $date
}