Página 1 de 4 1234 ÚltimoÚltimo
+ Responder ao Tópico



  1. #1

    Padrão Balance PCC com Failover Avançado (Sem Script)

    O objetivo deste tutorial é demonstrar como configurar um balanceamento de carga entre múltiplos links com um avançado Failover (Sem Scripts).

    Existem algumas formas de balancear links:
    - ECMP
    - NTH
    - PCC

    Para o balanceamento, iremos utilizar o PCC.
    O PCC ou “Per Connection Classifier”, marca os pacotes para que os mesmos sejam direcionados para o gateway certo, com isso a conexão ficará pertinente à certo gateway.

    Para o Failover, algumas pessoas usam ferramenta NetWatch para monitorar o Link. Outros usam scripts para executar ping periodicamente hosts remotos E então desabilitar rotas ou de alguma outra forma alterar o comportamento do roteamento/balanceamento.
    Mas nós iremos usar apenas /ip route para fazer esse monitoramento, sem NetWatch, sem script...

    Vamos lá.


    Cenário


    Clique na imagem para uma versão maior

Nome:	         CENARIO BALANCE.jpg
Visualizações:	20061
Tamanho: 	28,3 KB
ID:      	50501


    Eth5 – Lan 10.10.10.0/24
    IP no Mikrotik: 10.10.10.1

    Eth4 – LINK 1 - 10 MEGA - 192.168.30.0/24
    IP no Mikrotik: 192.168.30.2
    Gateway: 192.168.30.1

    Eth3 – LINK 2 - 10 MEGA - 192.168.31.0/24
    IP no Mikrotik: 192.168.31.2
    Gateway: 192.168.31.1



    REGRAS PARA OS IMPACIENTES

    /ip address
    add address=10.10.10.1/24 disabled=no interface=Eth5 network=10.10.10.0
    add address=192.168.30.2/24 disabled=no interface=Eth4 network=192.168.30.0
    add address=192.168.31.2/24 disabled=no interface=Eth3 network=192.168.31.0


    /ip firewall nat
    add action=masquerade chain=srcnat comment="### MASQUERADE ###" disabled=no out-interface=Eth4
    add action=masquerade chain=srcnat disabled=yes out-interface=Eth3


    /ip firewall mangle
    add action=mark-connection chain=prerouting comment="SITE POR LINK" connection-state=new disabled=no dst-


    address-list=LINK0 in-interface=Eth5 new-connection-mark=Sites0 passthrough=yes
    add action=mark-routing chain=prerouting connection-mark=Sites0 disabled=no in-interface=Eth5 new-routing-mark=Rota0 passthrough=no
    add action=mark-connection chain=prerouting connection-state=new disabled=no dst-address-list=LINK1 in-interface=Eth5 new-connection-mark=Sites1 passthrough=yes
    add action=mark-routing chain=prerouting connection-mark=Sites1 disabled=no in-interface=Eth5 new-routing-mark=Rota1 passthrough=no


    add action=add-dst-to-address-list address-list=ftp_con address-list-timeout=6h chain=prerouting comment="FTP FORA DO BALANCE" disabled=no dst-port=21 in-interface=Eth5 protocol=tcp
    add action=accept chain=prerouting disabled=no dst-address-list=ftp_con in-interface=Eth5
    add action=accept chain=prerouting comment="OUTRAS PORTAS FORA DO LOADBALACED" disabled=no dst-port=443,5000-6999,8080 in-interface=Eth5 protocol=tcp
    add action=accept chain=prerouting disabled=no dst-port=443,5000-6999,8080 in-interface=Eth5 protocol=udp


    add action=accept chain=prerouting comment="ACEITA REDE" disabled=no dst-address=192.168.30.0/24 in-interface=Eth5
    add action=accept chain=prerouting disabled=no dst-address=192.168.31.0/24 in-interface=Eth5


    add action=mark-connection chain=prerouting comment="MARCA CONEXAO ENTRADA PARA VOLTAR PELO MESMO LINK" connection-state=new disabled=no in-interface=Eth4 new-connection-mark=Eth4_conn passthrough=yes
    add action=mark-connection chain=prerouting connection-state=new disabled=no in-interface=Eth3 new-connection-mark=Eth3_conn passthrough=yes
    add action=mark-routing chain=output connection-mark=Eth4_conn disabled=no new-routing-mark=to_Eth4 passthrough=yes
    add action=mark-routing chain=output connection-mark=Eth3_conn disabled=no new-routing-mark=to_Eth3 passthrough=yes


    add action=mark-connection chain=prerouting comment="BALANCEANDO CONEXAO" connection-state=established disabled=no dst-address-type=!local in-interface=Eth5 new-connection-mark=Eth4_conn passthrough=yes per-connection-classifier=both-addresses-and-ports:2/0
    add action=mark-connection chain=prerouting connection-state=established disabled=no dst-address-type=!local in-interface=Eth5 new-connection-mark=Eth3_conn passthrough=yes per-connection-classifier=both-addresses-and-ports:2/1


    add action=mark-routing chain=prerouting comment="DIRECIONA MARCACAO PARA ROTEAMENTO" connection-mark=Eth4_conn disabled=no in-interface=Eth5 new-routing-mark=to_Eth4 passthrough=yes
    add action=mark-routing chain=prerouting connection-mark=Eth3_conn disabled=no in-interface=Eth5 new-routing-mark=to_Eth3 passthrough=yes


    /ip route
    add disabled=no distance=1 dst-address=200.154.56.80/32 gateway=192.168.30.1 scope=10 target-scope=10
    add disabled=no distance=1 dst-address=208.67.222.222/32 gateway=192.168.30.1 scope=10 target-scope=10
    add disabled=no distance=1 dst-address=200.160.2.3/32 gateway=192.168.31.1 scope=10 target-scope=10
    add disabled=no distance=1 dst-address=208.67.220.220/32 gateway=192.168.31.1 scope=10 target-scope=10


    add check-gateway=ping disabled=no distance=1 dst-address=192.168.56.1/32 gateway=208.67.220.220 scope=10 target-scope=10
    add check-gateway=ping disabled=no distance=1 dst-address=192.168.56.1/32 gateway=200.160.2.3 scope=10 target-scope=10
    add check-gateway=ping disabled=no distance=1 dst-address=192.168.57.1/32 gateway=208.67.222.222 scope=10 target-scope=10
    add check-gateway=ping disabled=no distance=1 dst-address=192.168.57.1/32 gateway=200.154.56.80 scope=10 target-scope=10


    add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=192.168.56.1 routing-mark=Rota0 scope=30 target-scope=10
    add disabled=no distance=2 dst-address=0.0.0.0/0 gateway=192.168.57.1 routing-mark=Rota0 scope=30 target-scope=10
    add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=192.168.57.1 routing-mark=Rota1 scope=30 target-scope=10
    add disabled=no distance=2 dst-address=0.0.0.0/0 gateway=192.168.56.1 routing-mark=Rota1 scope=30 target-scope=10


    add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=192.168.56.1 routing-mark=to_Eth3 scope=30 target-scope=10
    add disabled=no distance=2 dst-address=0.0.0.0/0 gateway=192.168.57.1 routing-mark=to_Eth3 scope=30 target-scope=10
    add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=192.168.57.1 routing-mark=to_Eth4 scope=30 target-scope=10
    add disabled=no distance=2 dst-address=0.0.0.0/0 gateway=192.168.56.1 routing-mark=to_Eth4 scope=30 target-scope=10


    add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=192.168.56.1 scope=30 target-scope=10
    add disabled=no distance=2 dst-address=0.0.0.0/0 gateway=192.168.57.1 scope=30 target-scope=10


    add disabled=no distance=20 dst-address=200.154.56.80/32 type=blackhole
    add disabled=no distance=20 dst-address=200.160.2.3/32 type=blackhole
    add disabled=no distance=20 dst-address=208.67.220.220/32 type=blackhole
    add disabled=no distance=20 dst-address=208.67.222.222/32 type=blackhole
    Última edição por AndrioPJ; 28-02-2014 às 00:20.

  2. #2

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    EXPLICAÇÃO DAS REGRAS IP ADDRESS e IP FIREWALL

    /ip address
    add address=10.10.10.1/24 disabled=no interface=Eth5 network=10.10.10.0
    add address=192.168.30.2/24 disabled=no interface=Eth4 network=192.168.30.0
    add address=192.168.31.2/24 disabled=no interface=Eth3 network=192.168.31.0


    /ip firewall nat
    add action=masquerade chain=srcnat comment="### MASQUERADE ###" disabled=no out-interface=Eth4
    add action=masquerade chain=srcnat disabled=yes out-interface=Eth3
    As regras acima criam a rede e faz o NAT.


    /ip firewall mangle
    add action=mark-connection chain=prerouting comment="SITE POR LINK" connection-state=new disabled=no dst-address-list=LINK0 in-interface=Eth5 new-connection-mark=Sites0 passthrough=yes
    add action=mark-routing chain=prerouting connection-mark=Sites0 disabled=no in-interface=Eth5 new-routing-mark=Rota0 passthrough=no
    add action=mark-connection chain=prerouting connection-state=new disabled=no dst-address-list=LINK1 in-interface=Eth5 new-connection-mark=Sites1 passthrough=yes
    add action=mark-routing chain=prerouting connection-mark=Sites1 disabled=no in-interface=Eth5 new-routing-mark=Rota1 passthrough=no
    As regras acima criam um address list para cadastrar ips que você queira que saia por um ou pelo outro Link.


    /ip firewall mangle
    add action=add-dst-to-address-list address-list=ftp_con address-list-timeout=6h chain=prerouting comment="FTP FORA DO BALANCE" disabled=no dst-port=21 in-interface=Eth5 protocol=tcp
    add action=accept chain=prerouting disabled=no dst-address-list=ftp_con in-interface=Eth5
    A regra acima evita problema com servidores FTP.


    /ip firewall mangle
    add action=accept chain=prerouting comment="OUTRAS PORTAS FORA DO LOADBALACED" disabled=no dst-port=443,5000-6999,8080 in-interface=Eth5 protocol=tcp
    add action=accept chain=prerouting disabled=no dst-port=443,5000-6999,8080 in-interface=Eth5 protocol=udp
    A regra acima retira outras portas do Balance.


    /ip firewall mangle
    add action=accept chain=prerouting comment="ACEITA REDE" disabled=no dst-address=192.168.30.0/24 in-interface=Eth5
    add action=accept chain=prerouting disabled=no dst-address=192.168.31.0/24 in-interface=Eth5
    A Regra acima aceita a conexão de cada Link.


    /ip firewall mangle
    add action=mark-connection chain=prerouting comment="MARCA CONEXAO ENTRADA PARA VOLTAR PELO MESMO LINK" connection-state=new disabled=no in-interface=Eth4 new-connection-mark=Eth4_conn passthrough=yes
    add action=mark-connection chain=prerouting connection-state=new disabled=no in-interface=Eth3 new-connection-mark=Eth3_conn passthrough=yes
    add action=mark-routing chain=output connection-mark=Eth4_conn disabled=no new-routing-mark=to_Eth4 passthrough=yes
    add action=mark-routing chain=output connection-mark=Eth3_conn disabled=no new-routing-mark=to_Eth3 passthrough=yes
    A regra acima marca a conexão de entrada do link para que ele volte pelo mesmo Link.


    /ip firewall mangle
    add action=mark-connection chain=prerouting comment="BALANCEANDO CONEXAO" connection-state=established disabled=no dst-address-type=!local in-interface=Eth5 new-connection-mark=Eth4_conn passthrough=yes per-connection-classifier=both-addresses-and-ports:2/0
    add action=mark-connection chain=prerouting connection-state=established disabled=no dst-address-type=!local in-interface=Eth5 new-connection-mark=Eth3_conn passthrough=yes per-connection-classifier=both-addresses-and-ports:2/1
    A Regra acima é responsável pelo balanceamento. Como os dois links tem o mesmo peso, então criamos apenas 2 regra.
    Caso Um link tenha peso maior, então precisa ter 1 regra a mais para esse Link.


    /ip firewall mangle
    add action=mark-routing chain=prerouting comment="DIRECIONA MARCACAO PARA ROTEAMENTO" connection-mark=Eth4_conn disabled=no in-interface=Eth5 new-routing-mark=to_Eth4 passthrough=yes
    add action=mark-routing chain=prerouting connection-mark=Eth3_conn disabled=no in-interface=Eth5 new-routing-mark=to_Eth3 passthrough=yes
    A regra acima direciona a marcação para cada Link.


    EXPLICAÇÃO DAS REGRAS /IP ROUTE

    Aqui vem o pulo de Gato.
    Antes de explicar a Regra, temos que entender 3 coisas:

    1 - IP para Teste (a sua escolha).

    • Para o Link 1, eu configurei um dos IP do OpenDNS (208.67.222.222) e o site do Terra (200.154.56.80).
    • Para o Link 2, eu configurei o outro IP do OpenDNS (208.67.220.220) e o site do Registrobr (200.160.2.3)


    2 - Criar um Gateway Falso (Fake) (a sua escolha).

    • Para o Link 1, eu decidi que o Gateway Falso seria 192.168.56.1
    • Para o Link 2, eu decidi que o Gateway Falso seria 192.168.57.1


    3 - E finalmente, o Gateway Verdadeiro (veja a faixa de IP de cada link).

    • Para o Link 1, Gateway Verdadeiro é 192.168.30.1
    • Para o Link 2, Gateway Verdadeiro é 192.168.31.1



    Então vamos lá.

    /ip route
    add disabled=no distance=1 dst-address=200.154.56.80/32 gateway=192.168.30.1 scope=10 target-scope=10
    add disabled=no distance=1 dst-address=208.67.222.222/32 gateway=192.168.30.1 scope=10 target-scope=10

    add disabled=no distance=1 dst-address=200.160.2.3/32 gateway=192.168.31.1 scope=10 target-scope=10
    add disabled=no distance=1 dst-address=208.67.220.220/32 gateway=192.168.31.1 scope=10 target-scope=10
    A Regra diz por qual Link cada IP de teste deverá sair.
    Ele irá testar um IP, senão tiver sucesso irá testar o outro IP, se também não tiver sucesso só então irá derrubar a conexão.


    /ip route
    add check-gateway=ping disabled=no distance=1 dst-address=192.168.56.1/32 gateway=208.67.220.220 scope=10 target-scope=10
    add check-gateway=ping disabled=no distance=1 dst-address=192.168.56.1/32 gateway=200.160.2.3 scope=10 target-scope=10


    add check-gateway=ping disabled=no distance=1 dst-address=192.168.57.1/32 gateway=208.67.222.222 scope=10 target-scope=10
    add check-gateway=ping disabled=no distance=1 dst-address=192.168.57.1/32 gateway=200.154.56.80 scope=10 target-scope=10
    A Regra acima cria um destino Virtual.
    As duas primeiras direcionam os IPs de teste para o Gateway Falso do Link 1 (192.168.56.1/32)
    As duas outras direcionam os outros IPs de teste para o Gateway Falso do Link 2 (192.168.57.1/32)


    /ip route
    add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=192.168.56.1 routing-mark=Rota0 scope=30 target-scope=10
    add disabled=no distance=2 dst-address=0.0.0.0/0 gateway=192.168.57.1 routing-mark=Rota0 scope=30 target-scope=10
    add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=192.168.57.1 routing-mark=Rota1 scope=30 target-scope=10
    add disabled=no distance=2 dst-address=0.0.0.0/0 gateway=192.168.56.1 routing-mark=Rota1 scope=30 target-scope=10
    As Regras acima criam a rota de saída dos IPs que foram marcados no firewall (address-list) para sair por um ou outro Link.


    /ip route
    add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=192.168.56.1 routing-mark=to_Eth3 scope=30 target-scope=10
    add disabled=no distance=2 dst-address=0.0.0.0/0 gateway=192.168.57.1 routing-mark=to_Eth3 scope=30 target-scope=10
    add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=192.168.57.1 routing-mark=to_Eth4 scope=30 target-scope=10
    add disabled=no distance=2 dst-address=0.0.0.0/0 gateway=192.168.56.1 routing-mark=to_Eth4 scope=30 target-scope=10
    As regras acima criam as rotas de saída da marcação do Balanceamento.


    /ip route
    add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=192.168.56.1 scope=30 target-scope=10
    add disabled=no distance=2 dst-address=0.0.0.0/0 gateway=192.168.57.1 scope=30 target-scope=10
    As regras acima é do Default Route, para aqueles que foram configurados no Firewall para sair por Fora do Balance.


    /ip route
    add disabled=no distance=20 dst-address=200.154.56.80/32 type=blackhole
    add disabled=no distance=20 dst-address=200.160.2.3/32 type=blackhole
    add disabled=no distance=20 dst-address=208.67.220.220/32 type=blackhole
    add disabled=no distance=20 dst-address=208.67.222.222/32 type=blackhole
    As regras acima corrigi um bug em algumas versões do Mikrotik.
    Quando um link caia, após retornar, as Rotas não eram recalculadas e todo o trafego continuava saindo por um unico Link.
    Com essas regras tudo é recalculado corretamente.
    Última edição por AndrioPJ; 28-02-2014 às 00:19.

  3. #3

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Muito Bom ! ! !
    Valew pela Contribuição amigo, já me tirou muitas duvidas aqui !

  4. #4

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Muito bom! Parabéns pela ótima iniciativa, vai ser de grande ajuda p/ muitos aqui no fórum.

    Tenho uma pergunta: no caso do exemplo postado, o cenário é c/ modems roteados, correto ?

    O que mudaria (além de não precisar adicionar IPs no IP>Address), se os modems estiverem em bridge ?

    Abraço.

  5. #5

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Citação Postado originalmente por FabianoMartins2 Ver Post
    Muito bom! Parabéns pela ótima iniciativa, vai ser de grande ajuda p/ muitos aqui no fórum.

    Tenho uma pergunta: no caso do exemplo postado, o cenário é c/ modems roteados, correto ?

    O que mudaria (além de não precisar adicionar IPs no IP>Address), se os modems estiverem em bridge ?

    Abraço.
    Citação Postado originalmente por Arthur Bernardes Ver Post
    Criar uma interface "PPPoE-Client" e nas configurações do balance, onde se define as interfaces cabeadas dos modens, defina as interfaces "PPPoE-Client".
    Olha, em parte o Arthur está certo.
    Basicamente nas regras de firewall basta alterar para a interface do PPoE.

    Contudo, em IP Route fica um pouco complicado fazer esse Failover.
    Em um breve teste, não foi possível criar um Gateway Fake em cima do PPoE, ele precisa de um IP para isso.

    Mas vou fazer mais testes.
    Quem sabe, adicionando um IP no mikrotik, direcionando esse IP para o PPoE... e depois criar um Gateway Fake em cima do IP criado.

  6. #6

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Parabéns pelo seu post. Me tirou dúvidas e com certeza vai ajudar muita gente daqui do fórum.

    Abraço!

  7. #7

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Ola pessoal!

    Primeiro, gostaria de agradecer a todos, pois resolvi vários dos meus problemas com dicas de usuários deste fórum.

    Quanto ao tópico, gostaria de saber quais alterações devo fazer para acrescentar mais uma LAN a este código. Tentei algumas coisas aqui (com src-address) mais não obtive sucesso. Se alguém puder dar uma força, agradeço desde já.

  8. #8

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Citação Postado originalmente por Jota Gutto Ver Post
    Ola pessoal!

    Primeiro, gostaria de agradecer a todos, pois resolvi vários dos meus problemas com dicas de usuários deste fórum.

    Quanto ao tópico, gostaria de saber quais alterações devo fazer para acrescentar mais uma LAN a este código. Tentei algumas coisas aqui (com src-address) mais não obtive sucesso. Se alguém puder dar uma força, agradeço desde já.
    crie uma bridge entre as duas interfaces lan.

    e nas regras de firewall que estava selecionado somente uma interface lan, modifique, selecione a bridge.

  9. #9

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Citação Postado originalmente por AndrioPJ Ver Post
    crie uma bridge entre as duas interfaces lan.

    e nas regras de firewall que estava selecionado somente uma interface lan, modifique, selecione a bridge.
    Obrigado AndrioPJ pela resposta.

    Quanto a fazer uma bridge entre as interfaces, não gostaria de fazer, pois queria uma interface exclusiva para o fim que desejo utilizá-la.

    Se tiver alguma outra ideia....

    Att.


  10. #10

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Citação Postado originalmente por Jota Gutto Ver Post
    Obrigado AndrioPJ pela resposta.

    Quanto a fazer uma bridge entre as interfaces, não gostaria de fazer, pois queria uma interface exclusiva para o fim que desejo utilizá-la.

    Se tiver alguma outra ideia....

    Att.

    você vai usar essa outra interface para que?

  11. #11

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Nada especial.
    Já temos um servidor aqui na empresa (funcionando) e tenho que acrescentar mais dois ligados ao ballance e acho que fica mais fácil a manutenção em diferentes interfaces, principalmente para mim que estou começando a usar o Mikrotik.

    Att.

  12. #12

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Citação Postado originalmente por AndrioPJ Ver Post
    Olha, em parte o Arthur está certo.
    Basicamente nas regras de firewall basta alterar para a interface do PPoE.

    Contudo, em IP Route fica um pouco complicado fazer esse Failover.
    Em um breve teste, não foi possível criar um Gateway Fake em cima do PPoE, ele precisa de um IP para isso.

    Mas vou fazer mais testes.
    Quem sabe, adicionando um IP no mikrotik, direcionando esse IP para o PPoE... e depois criar um Gateway Fake em cima do IP criado.
    Andrio, em caso dos modems ficarem roteados, isso prejudica o desempenho deles ? Pois já ouvi falar varias vezes que modems em bridge funcionam melhor pois não exige praticamente nada deles. Até me falaram que, em caso de modems em bridge, pode ser qualquer modem, pois não força em nada.

  13. #13

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Citação Postado originalmente por FabianoMartins2 Ver Post
    Andrio, em caso dos modems ficarem roteados, isso prejudica o desempenho deles ? Pois já ouvi falar varias vezes que modems em bridge funcionam melhor pois não exige praticamente nada deles. Até me falaram que, em caso de modems em bridge, pode ser qualquer modem, pois não força em nada.
    Olha, no ambiente de testes que montei funcionou normal, não tive qualquer problema.
    Mas testa ai, qualquer coisa você volta como estava antes....

  14. #14

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Citação Postado originalmente por AndrioPJ Ver Post
    Olha, no ambiente de testes que montei funcionou normal, não tive qualquer problema.
    Mas testa ai, qualquer coisa você volta como estava antes....
    Ok Andrio. Porem, tem um detalhe. Meu balance hoje é NTH por ROTAS. Não uso PCC. Eu estava pensando em mudar p/ PCC depois que vi o seu tópico muito bem explicado e fácil de entender sobre o PCC.

    Você conhece esse tipo de balance, NTH por ROTAS ? PCC é melhor do que ele ? Qual a sua opinião!

    Abraço.

  15. #15

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Citação Postado originalmente por FabianoMartins2 Ver Post
    Ok Andrio. Porem, tem um detalhe. Meu balance hoje é NTH por ROTAS. Não uso PCC. Eu estava pensando em mudar p/ PCC depois que vi o seu tópico muito bem explicado e fácil de entender sobre o PCC.

    Você conhece esse tipo de balance, NTH por ROTAS ? PCC é melhor do que ele ? Qual a sua opinião!

    Abraço.
    Nada!

  16. #16

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Citação Postado originalmente por FabianoMartins2 Ver Post
    Ok Andrio. Porem, tem um detalhe. Meu balance hoje é NTH por ROTAS. Não uso PCC. Eu estava pensando em mudar p/ PCC depois que vi o seu tópico muito bem explicado e fácil de entender sobre o PCC.

    Você conhece esse tipo de balance, NTH por ROTAS ? PCC é melhor do que ele ? Qual a sua opinião!

    Abraço.
    Citação Postado originalmente por FabianoMartins2 Ver Post
    Nada!
    PCC é melhor que NTH.
    O PCC classifica a conexão do inicio ao fim.

    No NTH, cada cliente usa uma WAN somente.
    No PCC, cada cliente pode usar todas as WAN, e ainda existe a possibilidade de classificar uma Rota para sair por determinada WAN.

  17. #17

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Citação Postado originalmente por AndrioPJ Ver Post
    PCC é melhor que NTH.
    O PCC classifica a conexão do inicio ao fim.

    No NTH, cada cliente usa uma WAN somente.
    No PCC, cada cliente pode usar todas as WAN, e ainda existe a possibilidade de classificar uma Rota para sair por determinada WAN.
    Ok Andrio, obrigado por responder.

    No caso do PCC, onde se faz a divisão, vejo colegas dizendo que a opção both addresses and ports (em Per connection Classifier), dá problemas c/ o numero de conexões. + ou - assim, quando mais clientes, mais endereços e portas sendo usados, dai surgem problemas como erros em algumas paginas, essa informação procede ou nada haver ?

    Abraço.

  18. #18

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Problema em ter mais de uma LAN no ballance resolvido (contratei um consultor mikrotik gringo), tudo funcionando.

    Quanto os modens roteados, usamos aqui e creio não ser problema pois o roteamento "pesado" é feito pela RB/PC.

    Att.

  19. #19

    Padrão Re: Balance PCC com Failover Avançado (Sem Script)

    Amigos a um tempo atraz uns 3 anos coloquei um balancer por pcc mais tive muitos problemas (paginas de banco, videos da globo.com, ftp etc.) então retirei o balancer e coloquei alguns clientes pra sairem pelo lik "A" e outros pelo link "B". desse modo o maior problema e não conseguir fazer os cliente do link "B" passa pelo cache.


    queria testar novamente o balancer com as resgras desse poste. o que me dizem ainda da problemas com bancos, etc?

    vale a pena uzar o balancer?

  20. #20

    Question Re: Balance PCC com Failover Avançado (Sem Script)

    Olá, Andrio... Parabéns pelo ótimo trabalho que vem fazendo, é Obrigado por nos dar um Help quando se trata de Mikrotik o bixo pega mesmo...

    estou com problema aqui pra configurar 2 Links Dedicado de operadoras diferente... a Operadora (a) tenho um Boco de IPv4 /27 e Operadora (b) somente o IP valido pra receber o Link... Operadora (a) tenho 8mb Full Duplex e Operadora (b) 5mb Full Duplex... eis a questão.

    preciso balancear a carga dos links... aqui está dessa forma... criei 2 range no pool 1 para sair o Link (a) e outro para sair o Link (b).... sendo os Clientes Dedicados, Comerciais e fazendas no Link (a) pois tenho o bloco /27 de ip validos pra repassar e Clientes Residenciais no Link (b) e tbm configurar um FailOver para quando um link cair os clientes serem redirecionados para o outro até o link DOWN voltar a ficar UP... vir-se e versa.

    Range Pool Clientes Dedicado (PPoE) - 10.10.17.0/24
    Range Pool Clientes Residencial (PPoE) - 10.10.15.0/24

    /ip address ( Configurações de recebimento dos Links RB 1100 )

    add address=10.10.11.1/24 disabled=no interface=SWITCH-10P network=10.10.11.0 ( Range Rede Enlace toda em Bridge )
    add address=182.193.1.30/30 disabled=no interface=LINK-M.M-ETH12 network=182.193.1.28 ( Entrada Link Fornecedor (a) )
    add address=171.87.1.30/30 disabled=no interface=LINK-G.N-ETH11 network=171.87.1.28 ( Entrada Link Fornecedor (b) )

    1º Duvida: o que seria ou pra que seria esse IP para Teste ?

    r:

    2º Duvida: o que seria ou pra que seria esse Gateway Falso (Fake) ?

    r:

    se não for muito em comodo poderia me explicar como configuro meu servidor em cima desses dados que coloquei aqui...


    Agradeço a todos que puderem me dar uma força tbm...