droptux

---

Olá !

No texto a seguir vou mostrar como configurar um Routerboard Mikrotik com as seguintes funcionalidades:

• Entrega de Dhcp para a rede local;
• Distribuir a navegação para a rede local;
• Configurar um proxy transparente para rede local;

Neste exemplo usei uma RB 750 com o RouterOS versão 6.27, então, aos trabalhos. Vamos considerar que o Rouberboard(RB) acabou de ser 'resetada'(caso não saiba o que estou dizendo esse link pode ajudar. Após o reset realizado vamos acessar o RB com o aplicativo Winbox, por padrão quando o RB é resetado o ip configurado na interface da porta 2 é o 192.168.88.1, o usuário é o 'admin' e não tem senha configurado para o usuário.

Configure a interface de rede do seu computador na mesma rede da RB, por exemplo 192.168.88.10/24, não precisamos setar o gateway no computador. Para estabelecermos a conexão com a RB conecte seu computar na porta 05 da RB(As portas 03 à 05 são escravas da 02, ou seja são um pequeno switch, tecnicamente você está conectado na porta 02 ).
No início do primeiro acesso uma janela será apresentada mostrando a configuração padrão que vem com a RB e da a opção de removê-la ou deixá-la. Vamos optar deixar a configuração de fábrica, removendo algumas das configurações antes de iniciarmos as nossas próprias configurações. O intuito aqui é fazermos a configuração básica listada anteriormente, então continuemos. Clicando no botão 'Ok' a janela será fechada, no menu do lado esquerdo vá até 'New Terminal' para abrir o terminal do RouterOS a partir dele todos os comandos aqui citados poderão ser executados. Os comandos abaixo removerão algumas das configurações padrões da RB que estão ativas neste momento:

Código :

/ip firewall filter remove [find]
/ip firewall nat remove [find]
/ip dhcp-client remove [find]
/ip dhcp-server remove [find]
/ip dhcp-server network remove [find]
/ip pool remove [find]

No próximo passo vamos alterar a interface que está com o ip configurado(que atualmente está na porta 02):

Código :

/ip address set interface=ether5-slave-local numbers=0

O comando acima altera para a interface 05 a regra de número 0 que anteriormente a interface setada nessa regra era a ether2-master-local.

Agora vamos deixar as interfaces independentes e não como está nesse momento sendo um pequeno switch:

Código :

/interface ethernet set ether3-slave-local master-port=none
/interface ethernet set ether4-slave-local master-port=none
/interface ethernet set ether5-slave-local master-port=none

Os comandos acima deixam as interfaces 3, 4 e 5 trabalhando como uma interfaces isoladas, após o enter sua conexão com a RB pode ser perdida, mas se após o primeiro enter você continuar a apertar o enter a conexão não vai cair(eu faço isso, aperto enter freneticamente rerere ).

Seguindo com as configurações vamos renomear as interfaces, para uma melhor identificação quando acessar a RB posteriormente:

Código :

/interface ethernet set name=ether1-Wan ether1-gateway
/interface ethernet set name=ether2-Lan ether2-master-local
/interface ethernet set name=ether3 ether3-slave-local
/interface ethernet set name=ether4 ether4-slave-local
/interface ethernet set name=ether5-Adm ether5-slave-local
 
/ip address set numbers=0 comment="Rede Gerencia"

Os comandos acima faz a nomeação das interfaces conforme nossa necessidade, em nosso cenário de exemplo temos a interface ether1 para uma interface WAN ether1-Wan e a interface ether2 como uma interface que irá falar com nossa rede local, ether2-Lan e muda o comentário da interface 5 que para esse exemplo é uma interface de gerencia, caso queira acessar sua RB fisicamente essa porta pode ficar disponível para tal acesso.

Após a configuração das interfaces vamos setar os endereços ips nas interfaces de rede, em nosso exemplo vamos usar as seguintes redes:

• Rede Wan: 192.168.2.2/24
• Rede Lan: 172.16.1.1/24

Setando ips nas interfaces:

Código :

/ip address
add address=192.168.2.2/24 comment="Rede Wan" interface=ether1-Wan
/ip address
add address=172.16.1.1/24 comment="Rede Lan" interface=ether2-Lan

Os comandos acima setam os ips nas respectivas interfaces, rede Wan que irá falar com nosso roteador que fala com a internet(nesse caso um modem Adsl), rede Lan que irá falar com nossa rede local, no caso um switch para distribuir para os outros hosts participantes da rede, impressoras, Pcs, notebooks, Access Points, etc.

Agora vamos configurar a rota padrão para que a RB possa navegar para internet:

Código :

/ip route
add comment="Rota Padrao" distance=1 gateway=192.168.2.1

O comando acima habilita a rota padrão da RB, tudo que não estiver em sua tabela de roteamento a RB envia para o seu gateway(que é o nosso próximo salto, o modem Adsl). Não coloquei o destino no comando acima que seria: qualquer destino. Nesta versão se o destino não é especificado o RouterOS entende que é qualquer destino. Segue o comando especificando o destino:

Código :

/ip route
add dst-address=0.0.0.0/0 comment="Rota Padrao" distance=1 gateway=192.168.2.1

Agora vamos configurar o serviço de dhcp para a rede local, poderíamos fazer todo o processo manualmente. Mas não o vamos, usaremos o setup que pode ser usado tanto na parte gráfica como também no terminal que é o nosso caso:

Código :

/ip dhcp-server> setup
Select interface to run DHCP server on
dhcp server interface: ether2-Lan
 
Select network for DHCP addresses
dhcp address space: 172.16.1.0/24
 
Select gateway for given network
gateway for dhcp network: 172.16.1.1
 
Select pool of ip addresses given out by DHCP server
addresses to give out: 172.16.1.10-172.16.1.50
 
Select DNS servers
dns servers: 172.16.1.1
 
Select lease time
lease time: 10m

Na primeira pergunta você irá colocar a interface que vai ouvir as solicitações de ips vindas da rede local, no nosso caso a ether2-Lan.
Na segunda pergunta vamos adicionar a rede que esse serviço de dhcp vai atender, no nosso caso como o ip já está setado na interface esse valor será preenchido automaticamente.
Na terceira pergunta vamos colocar o gateway da rede, no nosso caso é o ip da interface da rede local ether2-Lan.
Na quarta pergunta vamos definir quantos ips serão distribuídos para a rede local, no nosso exemplo eu configurei que seja distribuído do ip final 10 até o ip final 50, totalizando 40 ips.
Agora na quinta pergunta você vai colocar o Dns, o ip do servidor que irá responder as requisições de resolução de nome, no nosso exemplo será o própria RB.
Na sexta pergunta mostra o tempo concessão de um ip para um host da rede, aqui deixei o tempo padrão.

Após os passos acima seu serviço de dhcp já estará disponível para a rede local, agora vamos configurar o compartilhamento da internet para rede local:

Código :

/ip firewall nat
add action=masquerade chain=srcnat comment="Nat Geral" out-interface=ether1-Wan

O comando acima faz o masquerade de tudo que sair pela interface ether1-Wan, que é a interface que fala com o nosso modem Adsl. Falando bem superficialmente masquerade é uma técnica onde podemos mascarar toda uma rede privada(nesse caso, nossa rede local) para que saia para a internet com um ip público válido na internet.

Vamos configurar o serviço de dns no roteador, com o comando abaixo vamos habilitar o dns na RB onde as requisições de dns serão redirecionada para o dns público do Google:

Código :

/ip dns
set allow-remote-requests=yes servers=8.8.8.8,8.8.4.4

Com os passos acima já executados a rede local já vai estar navegando na internet, pode testar.

E pra finalizar vamos habilitar o serviço de proxy para rede local, proxy transparente. Lembrando que o proxy transparente só funciona com o protocolo http, requisições destinadas para o protocolo seguro https não são válidas para esse tipo de implementação de proxy, segue comandos:

Código :

/ip proxy
set enabled=yes port=3128
/ip firewall nat
add action=redirect chain=dstnat comment="Proxy Transparente" dst-port=80 in-interface=ether2-Lan protocol=tcp to-ports=3128

Os comandos acima habilita o proxy na RB que escutará na porta 3128 e também configura uma regra no firewall de redirecionamento, onde toda requisição que vier da interface da rede local com a porta de destino 80(http) e protocolo de transporte tcp, será redirecionado para a porta 3128 da RB onde estará rodando o serviço de proxy.

Com isso finalizamos as configurações básicas para que a RB disponibilize internet para uma pequena rede local, o Routerboard é uma ferramenta muito poderosa existem inúmeras e inúmeras funcionalidades. O que fizemos nesse texto não é nem a ponta do iceberg, rerere.