Bloquear o Viber na sua Rede Mikrotik

# Rastreador do Viber Script RouterOS v6.33rc33 #
# coloque no scheduler com Intervalo de 1 Minuto #
{
# STEP 1 coloque o Nome da sua Lista Negra aqui #
:global lst "Viber";
# Use DNS Entrys and add dst Address to the Firewall Address-list #
:foreach i in=[/ip dns cache all find where (name~"viber") && (type="A") ] do={
:local tmpAddress [/ip dns cache get $i address];
delay delay-time=10ms
:if ( [/ip firewall address-list find where address=$tmpAddress] = "") do={
:local cacheName [/ip dns cache get $i name] ;
:log info ("added entry: $cacheName $tmpAddress");
/ip firewall address-list add address=$tmpAddress list="$lst" comment=$cacheName;
}
}
}




# Bloqueador Viber RouterOS v6.33rc33 #
# coloque no scheduler com Intervalo de 6 Horas #
{
# STEP 2 coloque o nome da sua in-interface aqui #
:local iif "interface-name";
# STEP 3 coloque o nome do alvo da regra jump da firewall mangle aqui, ou deixa assim mesmo #
:local jt "viber_mangle";
# STEP 4 define o commentário da sua regra do jump aqui o deixa assim mesmo #
:local jtc "Jump to Vibe Chain";
# STEP 5 coloque o mesmo nome do STEP 1 la de cima aqui, mostra o IP do Destino, Servidor Viber se não mudou la em cima deixa assim mesmo #
:local dal "Viber";
# STEP 6 coloque o nome da marcação da Conexão rastreada aqui ou deixa assim mesmo #
:local ncm "viber_con";
# STEP 7 define aqui a sensibilidade da sua marcação da Conexão aqui, ou deixa assim mesmo #
# eu coloquei istu para não encheir a lista negra de mais, só vai acionar depois o sujeito com certeza estar usando muito #
:local size "100";
# STEP 8 coloque o commentario da sua Regra rastreadora da conexão aqui ou deixa assim mesmo #
:local cmc "Viber Connection";
# STEP 9 define aqui o nome da src-address-list aqui, esta lista mostra o IP do Computador o Cliente qual esta no Viber ou deixa assim mesmo #
:local sal "Viber User";
# STEP 10 coloque o commentário da regra qual marca o IP do Dispositivo do Cliente ou deixa assim mesmo #
:local sl "Viber Add Src to Address List";
# STEP 11 coloque o commentária da regra qual vai bloquear a Conexão ou deixa assim mesmo #
:local mwc "Drop Viber Con";
# STEP 12 coloque o nome do alvo da regra jump do firewall filter aqui, ou deixa assim mesmo #
:local fwf "viber_chain";
# DO NOT EDIT NOTHING BELOW, THIS CAN BREAK THE SCRIPT !!! #
:log warning ("Removing old Mangle=$jtc " . "Mangle=$cmc " . "Mangle=$sl " . "and Filter $jtc " . "else $mwc");
:put ("Removing old Mangle=$jtc " . "Mangle=$cmc " . "Mangle=$sl " . "and Filter $jtc " . "else $mwc");
/ip firewall mangle remove [ find comment="$jtc" ];
/ip firewall mangle remove [ find comment="$cmc" ];
/ip firewall mangle remove [ find comment="$sl" ];
/ip firewall filter remove [ find comment="$jtc" ];
/ip firewall filter remove [ find comment="$mwc" ];
:log warning ("Adding new Mangle=$jtc " . "Mangle=$cmc " . "Mangle=$sl " . "and Filter $jtc " . "else $mwc");
:put ("Adding new Mangle=$jtc " . "Mangle=$cmc " . "Mangle=$sl " . "and Filter $jtc " . "else $mwc");
/ip firewall mangle
add chain="forward" protocol=tcp in-interface=$iif dst-address-list="$dal" action=jump jump-target="$jt" comment="$jtc"
add chain="forward" protocol=udp in-interface=$iif dst-address-list="$dal" action=jump jump-target="$jt" comment="$jtc"
add chain="$jt" protocol=tcp in-interface=$iif connection-state=established,new dst-address-list="$dal" \
action=mark-connection new-connection-mark="$ncm" connection-bytes="$size-0" passthrough=yes comment="$cmc"
add chain="$jt" protocol=udp in-interface=$iif connection-state=established,new dst-address-list="$dal" \
action=mark-connection new-connection-mark="$ncm" connection-bytes="$size-0" passthrough=yes comment="$cmc"
add chain="$jt" dst-address-list="$dal" action=add-src-to-address-list address-list="$sal" address-list-timeout=6h \
connection-mark="$ncm" comment="$sl"
/ip firewall filter
add chain=forward protocol=tcp in-interface=$iif connection-mark="$ncm" action=jump jump-target="$fwf" comment="$jtc"
add chain=forward protocol=udp in-interface=$iif connection-mark="$ncm" action=jump jump-target="$fwf" comment="$jtc"
add chain="$fwf" protocol=tcp dst-port=80 connection-mark="$ncm" action=drop dst-address-list="$dal" src-address-list="$sal" comment="$mwc"
add chain="$fwf" protocol=tcp dst-port=443 connection-mark="$ncm" action=drop dst-address-list="$dal" src-address-list="$sal" comment="$mwc"
add chain="$fwf" protocol=tcp dst-port=5242 connection-mark="$ncm" action=drop dst-address-list="$dal" src-address-list="$sal" comment="$mwc"
add chain="$fwf" protocol=tcp dst-port=4244 connection-mark="$ncm" action=drop dst-address-list="$dal" src-address-list="$sal" comment="$mwc"
add chain="$fwf" protocol=udp dst-port=5243 connection-mark="$ncm" action=drop dst-address-list="$dal" src-address-list="$sal" comment="$mwc"
add chain="$fwf" protocol=udp dst-port=9785 connection-mark="$ncm" action=drop dst-address-list="$dal" src-address-list="$sal" comment="$mwc"
}








# Regras adicionais, se Você não quer deixar passar nem o cheiro do Viber #
# Insira no New Terminal, estas Regras vão ser statico #
/ip firewall address-list
add list=ViberStatic address="54.225.0.0-54.241.255.255" comment="Viber Static List"
add list=ViberStatic address="54.197.0.0-54.241.255.255" comment="Viber Static List"
/ip firewall filter
add chain=forward action=jump jump-target=static_viber_filter protocol=tcp dst-port=80 dst-address-list="ViberStatic"\
comment="Jump to Viber action"
add chain=forward action=jump jump-target=static_viber_filter protocol=tcp dst-port=443 dst-address-list="ViberStatic"\
comment="Jump to Viber action"
add chain=static_viber_filter action=drop comment="Drop Static Viber"


Boa Sorte !!!