Ajuda com Mikrotik

[nulltest]

Boa tarde Pessoal!

Descobri o fórum em torno de um mês e tem me ajudado em várias configurações. Parabéns a todos da comunidade! Espero poder contribuir em algo.

Estou com uma necessidade e gostaria da ajuda de vocês. Segue a topologia:



O escritório A é ligado com o B via fibra óptica. Em cada escritório tenho um switch que distribui rede/ip para os computadores via DHCP (rede 192.168.1.x) tornando uma única rede.

No quadro A tenho um Mikrotik (RB2011UiAS) com duas redes, uma para a rede dos computadores/cabeada (rede 192.168.1.x) e a outra para a rede wifi/visitantes (rede 192.168.22.x). Essas redes não conversam entre si devido as regras que eu criei no firewall. Contudo, gostaria da ajuda de vocês para saber como faço para que a mesma rede wifi chegue no escritório B, com o mesmo DHCP criado para rede wifi/visitantes, pois hoje só funciona no escritório A.

[edvan01]

vlam. resolve isso....
mas eu usaria uma bridghe. na mesma rede...
por exemplo... no ip ...168.22xx vc pode colocar um roteador no escritorio b com um ip ja desta rede... por ex... 192.168.22.200 e colocar o roteador com este ip fixo ligado na wan. as outras saidas em bridghe. ou seja desliga o dhcp do roteador sem fio ( ex que ira apenas repetir os ips da outra rede A. acho que isso ja resolveria... no meu caso... se fosse.. ja que nao trabalho com vlam porque nao sei configurar... da forma que vc precisa hoje.

[nulltest]

edvan01, primeiramente, obrigado por compartilhar a sua ideia.

Tentei fazer o que você disse, mas não obtive sucesso. No escritório B eu fiz a configuração do roteador com o IP 192.168.22.5 e desativei o DHCP, mas as portas LAN não pegaram nenhum IP.

Alguém que entende de vlan, consegue dar uma ajuda?

[alextaws]

Porta LAN não pega IP, apenas transmite, ao desativar o DHCP do roteador, ele deixar de fazer NAT, o roteador se tornar uma bridge, mais para isso o cabo que vem a internet, os ips ou melhor as configurações de rede, deve ser conectado também na porta LAN e não mais na WLAN

[nulltest]

Está ficando confuso, rsrs

[edvan01]

ele disse para vc desativar o dhcp.. e colocar o fio de chagada na porta lan mesmo.... porem.... como e uma bridghe vai repetir tudo ate a segunda rede que vc quer deixar escondida....

... ta mas qual... e a distancia de um para outro...?
e porque nao criar talves um ppoe e fazer a discagem no segundo predio... ?

[nulltest]

edvan01, essa discagem via pppoe as vezes me atenderia.

O site A ao B é ligado via fibra. No A é onde fica o Mikrotik (tem duas redes, a cabeada e wifi), já no site B só tem um conversor ligado ao switch, que pega o IP da rede cabeada.

Eu criei regras no firewall para que essas redes não se conversem. Mesmo assim, é possível fazer a discagem no site B para a rede wifi?

[edvan01]

bom... eu nao entendo muito... mas.... o que exatamente precisa... se for apenas fornecer internet para vizitantes... dos locais.. ele nao precisam estar em uma bridgh que ligue os dois pontos... ja que nao vai aver tranferencias de dados de um para o outro e sim apenas a saida para a internet...

entao pode sim se for este o objetivo... criar um servidor ppoe.. e colocar ele na interface bridghe ou na mesma que sai para a fibra... ( nao precisa ser uma bridghe.) so tem que ser a mesma... interface. criar um pool. e colocar no servidor pppoe. nao precisa criar dhcp.
feito isso crie o profile e coloque em local andress o ip. e em remote andress a pool. va no roteador e configure a porta wan. para ppoe com logim e senha. em (profile no server) coloque um ip da range para este login. resumindo e so criar um servidor pppoe. estude sobre isso veja videos... e jogar ele na mesma interface . mas sem dhcp

pode ainda... apenas deixar o roteador como ip estatico fixando o ip. mas ae precisaria criar umas regras la.

[andrecarlim]

Nossa tá uma salada master aqui! Antes de mais nada, me responde essa: você dispõe de mais uma rb no "escritório b"? Se sim, blz, da pra fazer, se não esquece, somente com switch gerenciável e daí a configuração é mais "difícil".

[andrecarlim]

Bom, não sei explicar o porque, mas senti uma grande vontade de fazer uma "receita de bolo" para ajudar esse rapaz, deve ter sido uma epifania moral ou algo assim, haha. De brinde deixei o firewall já configurado para fazer os bloqueios e o compartilhamento da internet em ambas as redes, fiz também um QoS para apimentar o negócio um pouco! Sobre o QoS preciso fazer algumas considerações, que são, levei em conta uma banda contratada de 20M/5M, deixei garantido 7M/1M para wifi e 13M/4M para a rede local, caso tenha banda sobrando ela é compartilhada entre as redes! Supondo que você tenha condição de instalar uma RB do lado "B" a configuração é essa:

RB do Escritório A, recebendo a internet através de PPPoE na ether1, cabo que vem do Escritório B ligado na ether2, rede local ligada na ether3 e rede wifi ligada na ether4.

/interface bridge
add name=br0
add name=br1

/interface pppoe-client
add add-default-route=yes disabled=no interface=ether1 name=pppoe-out1 password=teste user=teste

/interface vlan
add interface=ether2 name=vlan1000 vlan-id=1000
add interface=ether2 name=vlan2000 vlan-id=2000

/ip pool
add name=dhcp_pool2 ranges=192.168.22.2-192.168.22.254
add name=dhcp_pool1 ranges=192.168.1.64-192.168.1.254

/ip dhcp-server
add address-pool=dhcp_pool2 disabled=no interface=br1 lease-time=1h name=dhcp2
add address-pool=dhcp_pool1 disabled=no interface=br0 lease-time=1d name=dhcp1

/interface bridge port
add bridge=br0 interface=ether3
add bridge=br0 interface=vlan1000
add bridge=br1 interface=ether4
add bridge=br1 interface=vlan2000

/ip address
add address=192.168.1.1/24 interface=br0 network=192.168.1.0
add address=192.168.22.1/24 interface=br1 network=192.168.22.0

/ip dhcp-server network
add address=192.168.1.0/24 dns-server=192.168.1.1,8.8.8.8,8.8.4.4 gateway=192.168.1.1
add address=192.168.22.0/24 dns-server=192.168.22.1,8.8.8.8,8.8.4.4 gateway=192.168.22.1

/ip dns
set allow-remote-requests=yes servers=8.8.8.8,8.8.4.4

/ip firewall filter
add action=accept chain=input comment="Accept Established and Related everything" connection-state=established
add action=accept chain=input connection-state=related
add action=accept chain=input comment="Accept Winbox" dst-port=8291 protocol=tcp
add action=accept chain=forward comment="Drop access between this networks" dst-address=192.168.22.0/24 src-address=192.168.1.0/24
add action=accept chain=forward dst-address=192.168.1.0/24 src-address=192.168.22.0/24
add action=accept chain=input comment="Accept enerything from local bridges" in-interface=br0
add action=accept chain=input in-interface=br1
add action=drop chain=input comment="Drop everything from Wan" in-interface=pppoe-out1
add action=drop chain=input in-interface=ether1

/ip firewall nat
add action=masquerade chain=srcnat out-interface=pppoe-out1 src-address=192.168.1.0/24
add action=masquerade chain=srcnat out-interface=pppoe-out1 src-address=192.168.22.0/24

/queue simple
add max-limit=5M/20M name=master-20M-5M target=""
add limit-at=4M/13M max-limit=4950k/19950k name=rede-local-13M-4M parent=master-20M-5M target=192.168.1.0/24
add limit-at=1M/7M max-limit=4950k/19950k name=rede-local-7M-1M parent=master-20M-5M target=192.168.22.0/24

/system identity
set name=office-side-A



RB do Escritório B, recebendo a internet através da RB do Escritório A, cabo que vem do Escritório A ligado na ether2, rede local ligada na ether3 e rede wifi ligada na ether4.

/interface bridge
add name=br0
add name=br1

/interface vlan
add interface=ether2 name=vlan1000 vlan-id=1000
add interface=ether2 name=vlan2000 vlan-id=2000

/interface bridge port
add bridge=br0 interface=ether3
add bridge=br0 interface=vlan1000
add bridge=br1 interface=ether4
add bridge=br1 interface=vlan2000

/ip address
add address=192.168.1.2/24 interface=br0 network=192.168.1.0

/ip route
add distance=1 gateway=192.168.1.1

/system identity
set name=office-side-B

[nulltest]

andrecarlim, assim como fiz em privado, estou agradecendo em público. Muito obrigado pela a ajuda e pela disposição em compartilhar todo o seu conhecimento. É difícil achar pessoas assim, que estão dispostas a ajudar. Como o edvan01 também ajudou através do conhecimento que ele tem, eu agradeço você também. Precisamos de mais pessoas assim, aliás, o Brasil e o mundo! Na verdade você passou todo o script e é só executar, nem tem o que falar e sim agradecer!