Página 1 de 2 12 ÚltimoÚltimo
+ Responder ao Tópico



  1. Boa noite galera do Under, sei que existem varios Tutos aki de Change IPO, porém nenhum consegui fazer funcionar no meu MK, por favor se alguem que saiba realmente fazer ele funcionar estarei remunerando o bom trabalho feito.... Obrigado... e aguardo...

    MSN: fa_de_araujo@hotmail.com

    Valeu!!!

  2. Para não dizerem que nunca fui bonzinho... esse ai é do dyndns.



    Funciona em versões 3.30 e 4.x (copiei de um 3.30 esse aqui)

    Código :
    # Set needed variables
    :local username "seu_usuario"
    :local password "sua_senha"
    :local hostname "seu_host.dyndns.algumacoisa"
     
    :global dyndnsForce
    :global previousIP
     
    # print some debug info
    :log info ("dyndns-update: username = $username")
    :log info ("dyndns-update: password = $password")
    :log info ("dyndns-update: hostname = $hostname")
    :log info ("dyndns-update: previousIP = $previousIP")
     
    # get the current IP address from the internet (in case of double-nat)
    /tool fetch mode=http address="checkip.dyndns.org" src-path="/" dst-path="/dyndns.checkip.html"
    :local result [/file get dyndns.checkip.html contents]
     
    # parse the current IP result
    :local resultLen [:len $result]
    :local startLoc [:find $result ": " -1]
    :set startLoc ($startLoc + 2)
    :local endLoc [:find $result "</body>" -1]
    :local currentIP [:pick $result $startLoc $endLoc]
    :log info "dyndns-update: currentIP = $currentIP"
     
    # Determine if dyndns update is needed
    # more dyndns updater request details available at http://www.dyndns.com/developers/specs/syntax.html
    :if (($currentIP != $previousIP) || ($dyndnsForce = true)) do={
        :set dyndnsForce false
        :set previousIP $currentIP
        /tool fetch user=$username password=$password mode=http address="members.dyndns.org" src-path="/nic/update?hostname=$hostname&myip=$currentIP" dst-path="/dyndns.txt"
        :local result [/file get dyndns.txt contents]
        :log info ("dyndns-update: Dyndns update needed")
        :log info ("dyndns-update: Dyndns Update Result: ".$result)
        :put ("Dyndns Update Result: ".$result)
    } else={
        :log info ("dyndns-update: No dyndns update needed")
    }
    Última edição por sergio; 26-08-2010 às 20:31.



  3. Hehehehee.... é isso ai Sérgio lá vai os que eu uso Mk 3.x:
    Código :
    # Define Variaveis de Usuarios
    :global ddnsuser "user"
    :global ddnspass "senha"
    :global ddnshost "provedor.changeip.org"
     
    # Define Variaveis Globais
    :global ddnsip
    :global ddnslastip
    :if ([ :typeof $ddnslastip ] = nil ) do={ :global ddnslastip "0" }
     
    :global ddnsinterface
    :global ddnssystem ("mt-" . [/system package get system version] )
     
    # Define Variaveis Locais
    :local int
     
    # Pegando Informacao da Interface
    # Rotas marcadas como Default
    :foreach int in=[/ip route find dst-address=0.0.0.0/0 active=yes ] do={ 
      :if ([:typeof [/ip route get $int routing-mark ]] != str ) do={
         :global ddnsinterface [/ip route get $int interface]
      } 
    }
     
    # Pegando o IP atual da Interface.
    :global ddnsip [ /ip address get [/ip address find interface=$ddnsinterface ] address ]
     
    # Comparando o IP pego.
    :if ([ :typeof $ddnsip ] = nil ) do={
       :log info ("DDNS: Nao existe ip na " . $ddnsinterface . ", cheque por favor.")
    } else={
     
      :if ($ddnsip != $ddnslastip) do={
     
        :log info "DDNS: Enviando Atualizacao!"
        :log info [ :put [/tool dns-update name=$ddnshost address=[:pick $ddnsip 0 [:find $ddnsip "/"] ] key-name=$ddnsuser key=$ddnspass ] ]
        :global ddnslastip $ddnsip
     
      } else={ 
        :log info "DDNS: Atualizacao Desnecessaria."
      }
     
    }
     
    # Final do Script

    MK 4.x / 5.x:
    Código :
    #=======================================#
    # Edite seus detalhes / Configurando abaixo.
    #=======================================#
    :global ddnsuser "user"
    :global ddnspass "senha"
    :global ddnshost "provedor.changeip.org"
    :global ddnsinterface "interface"
    #=======================================#
    # Fim da definicao das configuracoes do usuario.
    #=======================================#
     
    :global ddnssystem ("mt-" . [/system package get [/system package find name=system] version] )
    :global ddnsip [ /ip address get [/ip address find interface=$ddnsinterface] address ]
    :global ddnslastip
     
    :if ([:len [/interface find name=$ddnsinterface]] = 0 ) do={ :log info "DDNS: Interface nao existe $ddnsinterface, por favor verifique a configuracao." }
     
    :if ([ :typeof $ddnslastip ] = "nothing" ) do={ :global ddnslastip 0.0.0.0/0 }
     
    :if ([ :typeof $ddnsip ] = "nothing" ) do={
     
    :log info ("DDNS: Nenhum IP presente na interface " . $ddnsinterface . ", por favor verifique.")
     
    } else={
     
      :if ($ddnsip != $ddnslastip) do={
     
        :log info "DDNS: Enviando atualizacao!"
        :log info [ :put [/tool dns-update name=$ddnshost address=[:pick $ddnsip 0 [:find $ddnsip "/"] ] key-name=$ddnsuser key=$ddnspass ] ]
        :global ddnslastip $ddnsip
     
      } else={ 
     
        :log info "DDNS: Atualizacao desnecessaria."
     
      }
     
    }

    Espero que o pessoal se satisfaçam...
    Nem preciso falar que não postarei da versão 2.x por regras do forum.
    Gostaram agradeça.

  4. Vai ai mamão com açucar!!!
    Enhanced Dynamic DNS Solutions
    Crie teu USUARIO/DOMINIO

    #int-DDNS.Info
    /tool dns-update name=USUARIO.ddns.info address=127.0.0.255 key-name=USUARIO key="SENHA"



  5. Obrigado aos amigos que se prontificaram, (sergio / minelli e neydourado).... Funcionou que é uma beleza.... ta mastigadinho este post, acho que poderia até ficar tipo fixo né, pois procurei muitos aqui e nenhum funcionou perfeitamente.... Obrigado a todos.!!






Tópicos Similares

  1. Script VPN com IP dinâmico no servidor
    Por danilomp no fórum Redes
    Respostas: 4
    Último Post: 15-01-2015, 23:07
  2. Ajuda pra testar meu script de instalação do Postfix
    Por lidzky no fórum Servidores de Rede
    Respostas: 0
    Último Post: 24-02-2006, 00:34
  3. Problemas com meu script de firewall alguem pode por favor olhar?
    Por fisiconuclear18 no fórum Servidores de Rede
    Respostas: 4
    Último Post: 09-02-2006, 16:12
  4. Meu script de firewall, alguém pode dar uma olhada?
    Por fisiconuclear18 no fórum Servidores de Rede
    Respostas: 3
    Último Post: 25-11-2005, 10:27
  5. Mensagem quando executo meu script de firewall
    Por Wal no fórum Servidores de Rede
    Respostas: 8
    Último Post: 09-11-2003, 02:13

Visite: BR-Linux ·  VivaOLinux ·  Dicas-L